            * = $0800
            incbin lincolnday.vsf.attrib
            * = $0c00
            incbin lincolnday.vsf.colmap

            * = $1000
            incprg america

            * = $2000
            incbin lincolnday.vsf.bitmap

            * = $4800
            incbin lincolnite.vsf.attrib
            * = $4c00
            incbin lincolnite.vsf.colmap

            * = $6000
            incbin lincolnite.vsf.bitmap


ffcount = $ab
zpsrc   = $ac
zpdst   = $ae

            * = $8000

            lda #$0f
            sta $d021
            sta $d020
            lda #$80
            sta $291
            ;LDA #$0B
            jsr setd011

            lda #$16
            sta $d018

            lda #<txt
            ldy #>txt
            jsr $ab1e
            lda #<txt2
            ldy #>txt2
            jsr $ab1e

            LDA #$1B
            jsr setd011
            SEI
            lda #$7f
            sta $dc0d
            lda $dc0d
            lda #<irq
            sta $0314
            lda #>irq
            sta $0315
            lda #<nmi
            sta $0318
            lda #>nmi
            sta $0319
            lda #$1b
            sta $d012
            ;lda #$1b
            sta $d011
            lda #$01
            sta $d019
            sta $d01a
            cli
            lda #0
            jsr $1000
            jsr inkey1


            ldy #$00
            jsr init1
            sty zpsrc
            sty ffcount

labl2       lda (zpsrc),y
            cmp #$20
            beq nodec
            sec
            sbc #$01
            sta (zpsrc),y
nodec
            iny
            bne labl2
            inc zpsrc+1
            dex
            bne labl2
            jsr init1
            dec ffcount
            bne labl2


            jsr unkey
            ;LDA #$0B
            jsr setd011
            LDX #$00
            stx flip+1 ;reset at start

            jsr col1

            LDA #$38
            STA $D018
            LDA #$D8
            STA $D016
            lda #$0C
            STA $D020
            STA $D021
            LDA #$3B
            jsr setd011

mainloop

            jsr inkey1

            inc flip+1

            LDA #$3B
            jsr setd011

flip        lda #0
            and #01
            bne setcol2
setcol1
            lda #$0C
            STA $D020
            jsr col1
            beq disp
setcol2
            lda #$00
            STA $D020
            jsr col2
disp
            LDA #$3B
            jsr setd011
            jsr unkey
            bne mainloop
;--------------------------
col1        lda #$93
            ldx #$08
            bne set2

col2        lda #$92
            ldx #$48


set2        sta $dd00
            stx zpsrc+1
            ldy #0
            sty zpsrc
            sty zpdst
            lda #$d8
            sta zpdst+1
            ldx #$04
lpc1        LDA (zpsrc),y
            sta (zpdst),y
            iny
            bne lpc1
            inc zpsrc+1
            inc zpdst+1
            dex
            bne lpc1
            rts

;----------------------------------
inkey1      lda $dc00
            and $dc01
            and #$10
            bne inkey1
            rts
;----------------------------------
unkey       lda $dc00
            and $dc01
            and #$10
            beq unkey
            rts
;----------------------------------
setd011
            ldx $d011
            bpl *-3
            STA $D011
            rts
;----------------------------------
init1
            lda #$04
            tax
            sta zpsrc+1
            rts
;----------------------------------
irq         asl $d019
            ;inc $d020
            jsr $1003
            ;dec $d020
            jmp $ea31
nmi         rti


txt         byte $90,$93,$0d,$0d
            petc "----------------------------------------"
            byte $97,$0d
            petc "   Lincoln Memorial by James D. Sachs   "
            byte $98,$0d
            petc "          Day & Night versions          "
            byte 0

txt2
            byte $90,$0d
            petc "----------------------------------------"
            byte $9c,$0d
            petc "'America' tune composed by: DRAX/VIB+MON"
            byte $9a,$0d
            petc "Press space to flip pics - iAN CooG/HVSC"
            byte $90,$0d
            petc "----------------------------------------"
            byte 0

